Περιεχόμενα
Δείκτης 🔎︎

# SUMIFS

Επιστρέφει το άθροισμα των τιμών των κελιών σε μια περιοχή που πληρεί πολλαπλά κριτήρια σε πολλαπλές περιοχές.

Αυτή η συνάρτηση είναι διαθέσιμη από το LibreOffice 4.0.

#### Σύνταξη

SUMIFS(Περιοχή_Συναρτ; Περιοχή1; Κριτήριο[; Περιοχή2; Κριτήριο2][; … ; [Περιοχή127; Κριτήριο127]])

Περιοχή_συνάρτησης – απαιτούμενο όρισμα. Είναι μια περιοχή κελιών, ένα όνομα μιας ονοματισμένης περιοχής, ή μια ετικέτα μιας στήλης ή μιας γραμμής που περιέχουν τιμές για τον υπολογισμό του αθροίσματος.

Περιοχή1 - Απαιτούμενο όρισμα. Είναι περιοχή κελιών, όνομα ονοματισμένης περιοχής, ή ετικέτα στήλης ή γραμμής, στην οποία εφαρμόζεται το αντίστοιχο κριτήριο.

Κριτήριο: Κριτήριο είναι μια μοναδική αναφορά κελιού, αριθμού, ή κειμένου. Χρησιμοποιείται σε συγκρίσεις με περιεχόμενα κελιού.

Μια αναφορά σε κενό κελί ερμηνεύεται ως η αριθμητική τιμή 0.

Μια σύμφωνη έκφραση μπορεί να είναι:

- Μια αριθμητική ή λογική τιμή. Ένα σύμφωνο περιεχόμενο κελιού ισούται με τον αριθμό ή τη λογική τιμή.

- Μια τιμή που ξεκινά με έναν συγκριτή (<, <=, =, >, >=, <>).

  Για =, εάν η τιμή είναι κενή συμφωνεί με κενά κελιά.

  Για <>, εάν η τιμή είναι κενή συμφωνεί με μη κενά κελιά.

  Για <>, εάν η τιμή δεν είναι κενή, συμφωνεί με οποιοδήποτε περιεχόμενο κελιού εκτός από την τιμή, συμπεριλαμβανομένων των κενών κελιών.

  Σημείωση: "=0" δεν συμφωνεί με κενά κελιά.

  Για = και <>, εάν η τιμή δεν είναι κενή και δεν μπορεί να ερμηνευτεί ως τύπος αριθμού ή ένας από τους υποτύπους του και η ιδιότητα Τα κριτήρια αναζήτησης = και <> πρέπει να εφαρμόζονται σε ολόκληρα κελιά είναι σημειωμένη, η σύγκριση είναι ως προς ολόκληρα τα περιεχόμενα του κελιού· εάν ξεσημειωθεί, η σύγκριση είναι ως προς οποιοδήποτε τμήμα του πεδίου που ταιριάζει με τα κριτήρια. Για = και <>, εάν η τιμή δεν είναι κενή και δεν μπορεί να ερμηνευθεί ως τύπος αριθμού, εφαρμόζεται ένας από τους υποτύπους του.

- Άλλη τιμή κειμένου. Εάν η ιδιότητα Search criteria = and <> must apply to whole cells (Τα κριτήρια αναζήτησης = και <> πρέπει να εφαρμοστούν σε ολόκληρα κελιά) είναι αληθής, η σύγκριση είναι ως προς τα περιεχόμενα ολόκληρου του κελιού, εάν είναι ψευδής η σύγκριση είναι ως προς οποιοδήποτε υποτμήμα του πεδίου που ταιριάζει με τα κριτήρια. Η έκφραση μπορεί να περιέχει κείμενο, αριθμούς, κανονικές εκφράσεις ή σύμβολα υποκατάστασης (Εάν είναι ενεργοποιημένα στις επιλογές υπολογισμού).

Περιοχή2 – Προαιρετικά. Η Περιοχή2 και όλα τα ακόλουθα σημαίνουν το ίδιο με την Περιοχή1.

Κριτήριο2 – Προαιρετικό. Κριτήριο2 και όλα τα παρακάτω σημαίνουν το ίδιο με το κριτήριο.

The search supports wildcards or regular expressions. With regular expressions enabled, you can enter "all.*", for example to find the first location of "all" followed by any characters. If you want to search for a text that is also a regular expression, you must either precede every regular expression metacharacter or operator with a "\" character, or enclose the text into \Q...\E. You can switch the automatic evaluation of wildcards or regular expression on and off in LibreOffice - Preferences Tools - Options - LibreOffice Calc - Calculate.

Όταν χρησιμοποιείτε συναρτήσεις όπου ένα ή περισσότερα ορίσματα είναι συμβολοσειρές κριτηρίων αναζήτησης που αντιπροσωπεύουν κανονική έκφραση, η πρώτη προσπάθεια είναι η μετατροπή των κριτηρίων συμβολοσειρών σε αριθμούς. Παραδείγματος χάρη, το ".0" θα μετατραπεί σε 0.0 κ.ο.κ. Εάν είναι πετυχημένο, η συμφωνία δεν θα είναι συμφωνία κανονικής έκφρασης, αλλά αριθμητική συμφωνία. Όμως, όταν αλλάζετε στις τοπικές ρυθμίσεις όπου ο δεκαδικός διαχωριστής δεν είναι η τελεία, η μετατροπή της κανονικής έκφρασης λειτουργεί. Για να εξαναγκάσετε την αξιολόγηση της κανονικής έκφρασης αντί για την αριθμητική έκφραση, χρησιμοποιήστε κάποια έκφραση που δεν μπορεί να παρανοηθεί ως αριθμητική, όπως ".[0]", ή ".\0", ή "(?i).0".

Οι Περιοχή_συνάρτησης και Περιοχή1, Περιοχή2... πρέπει να έχουν το ίδιο μέγεθος, αλλιώς η συνάρτηση επιστρέφει err:502 - άκυρο όρισμα.

Η λογική σχέση μεταξύ κριτηρίων μπορεί να οριστεί ως λογικό AND (συνδυασμός). Με άλλα λόγια, εάν και μόνο εάν πληρούνται όλα τα κριτήρια, μια τιμή από το αντίστοιχο κελί της δεδομένης Περιοχής_συνάρτησης λαμβάνεται υπόψη στον υπολογισμό.

Η συνάρτηση μπορεί να έχει μέχρι 255 ορίσματα, που σημαίνει ότι μπορείτε να ορίσετε 127 περιοχές κριτηρίων και κριτήρια για αυτά.

Εάν το κελί περιέχει TRUE, θεωρείται ως 1, εάν ένα κελί περιέχει FALSE – ως 0 (μηδέν).

Αυτή η συνάρτηση είναι τμήμα του προτύπου της μορφής Open Document για εφαρμογές γραφείου (OpenDocument) έκδοσης 1.2. (ISO/IEC 26300:2-2015)

#### Παράδειγμα

Θεωρήστε τον ακόλουθο πίνακα

| A | B | C
1 | Όνομα προϊόντος | Πωλήσεις | Έσοδα
2 | μολύβι | 20 | 65
3 | στυλό | 35 | 85
4 | σημειωματάριο | 20 | 190
5 | βιβλίο | 17 | 180
6 | κασετίνα | όχι | όχι

Σε όλα τα παρακάτω παραδείγματα, οι περιοχές για τον υπολογισμό περιέχουν τη γραμμή #6 που αγνοείται, επειδή περιέχει κείμενο.

#### Απλή χρήση

=SUMIFS(B2:B6;B2:B6;">=20")

Υπολογίζει το άθροισμα των τιμών στην περιοχή B2:B6 που είναι μεγαλύτερες από ή ίσες με 20. Επιστρέφει 75, επειδή η πέμπτη γραμμή δεν ικανοποιεί το κριτήριο.

=SUMIFS(C2:C6;B2:B6;">=20";C2:C6;">70")

Υπολογίζει το άθροισμα των τιμών στην περιοχή C2:C6 που είναι μεγαλύτερες από 70 και αντιστοιχεί στα κελιά της περιοχής B2:B6 με τιμές μεγαλύτερες από ή ίσες με 20. Επιστρέφει 275, επειδή η δεύτερη και η πέμπτη γραμμή δεν ικανοποιούν τουλάχιστον ένα κριτήριο.

#### Χρήση κανονικών παραστάσεων και ένθετων συναρτήσεων

=SUMIFS(C2:C6;B2:B6;">"&MIN(B2:B6);B2:B6;"<"&MAX(B2:B6))

Υπολογίζει το άθροισμα των τιμών στην περιοχή C2:C6 που αντιστοιχούν σε όλες τις τιμές της περιοχής B2:B6, εκτός από την ελάχιστη και τη μέγιστη. Επιστρέφει 255, επειδή η τρίτη και η πέμπτη γραμμή δεν ικανοποιούν τουλάχιστον ένα κριτήριο.

=SUMIFS(C2:C6;A2:A6;"pen.*";B2:B6;"<"&MAX(B2:B6))

Υπολογίζει το άθροισμα των τιμών στην περιοχή C2:C6 που αντιστοιχούν σε όλα τα κελιά της περιοχής A2:A6 που αρχίζουν με "pen" και σε όλα τα κελιά της περιοχής B2:B6, εκτός από το μέγιστό του. Επιστρέφει 65, επειδή μόνο η δεύτερη γραμμή ικανοποιεί όλα τα κριτήρια.

#### Αναφορά σε ένα κελί ως ένα κριτήριο

Αν χρειάζεται να αλλάξετε ένα κριτήριο εύκολα, μπορεί να θέλετε να το ορίσετε σε ένα ξεχωριστό κελί και να χρησιμοποιήσετε μια αναφορά σε αυτό το κελί στη συνθήκη της συνάρτησης SUMIFS. Παραδείγματος χάρη, η παραπάνω συνάρτηση μπορεί να ξαναγραφτεί ως εξής:

=SUMIFS(C2:C6;A2:A6;E2&".*";B2:B6;"<"&MAX(B2:B6))

Αν E2 = pen, η συνάρτηση επιστρέφει 65, επειδή ο σύνδεσμος στο κελί αντικαθίσταται με το περιεχόμενό του.

Σχετικά θέματα

[text/scalc/01/04060106.xhp#sum_head not found]., SUMIF

COUNTIFS, MINIFS, MAXIFS, AVERAGEIFS, SUMIFS

Κατάλογος κανονικών εκφράσεων